Mạch Điều Khiển Động Cơ VNH2SP30 30A

Mạch Điều Khiển Động Cơ VNH2SP30 30A thay thế cho module L298. Ngõ ra được thiết kế pad chì có kích thước lỗ  khớp với domino để người dùng có thể đấu dây điện loại lớn.

Chú ý : nếu bạn dùng với motor công suất cao (> 6A) ~ tỏa nhiệt lớn ==> dán thêm tản nhiệt để đảm bảo hiệu suất và tuổi thọ.

THÔNG SỐ KỸ THUẬT

• Điện áp hoạt động: 5.5 – 16VDC
• Dòng đỉnh: 30A
• Dòng liên tục: 14A
• Current sense (chân đo dòng): có thể kết nối chân Analog của Arduino để đo
• Trở kháng nội của MOSFET : 19mΩ
• Tần số băm xung tối đa : 20kHz
• Bảo vệ quá nhiệt và quá áp.

Lưu ý : Mạch hoạt động điện áp tối đa 16V, Nếu cấp điện áp cao hơn, mạch không hư, khi đó chế độ bảo vệ quá áp sẽ hoạt động mạch bị ngắt tạm thời ngắt mạch.

Hình Mạch Điều Khiển Động Cơ VNH2SP30 30A

———————–CODE THAM KHẢO———————–

/*
 *  Kết nối:
 *          Driver              Arduino
 *           5V                   5V
 *           GND                  GND
 *           EN                   A0
 *           INA                  7
 *           INB                  8
 *           PWM                  5
 *           
 *  Cấp nguồn 5.5 - 16V cho Shield.
 *  Mở Serial Monitor:
 *  Gửi '1' dừng động cơ.
 *  Gửi '2' quay 2 động cơ.
 *  Gửi '3' đảo chiều động cơ.
 *  Gửi '+' tăng tốc độ động cơ.
 *  Gửi '-' giảm tốc độ động cơ.
 */


#define BRAKE 0
#define CW    1
#define CCW   2
#define CS_THRESHOLD 15   

#define MOTOR_A1_PIN 7
#define MOTOR_B1_PIN 8
#define PWM_MOTOR_1 5
#define EN_PIN_1 A0
#define MOTOR_1 0


short usSpeed = 150;  
unsigned short usMotor_Status = BRAKE;
 
void setup()                         
{
  pinMode(MOTOR_A1_PIN, OUTPUT);
  pinMode(MOTOR_B1_PIN, OUTPUT);
  pinMode(PWM_MOTOR_1, OUTPUT);
  pinMode(EN_PIN_1, OUTPUT);
  digitalWrite(EN_PIN_1, HIGH);

  Serial.begin(9600);              
  Serial.println(); 
  Serial.println("Enter number for control option:");
  Serial.println("1. STOP");
  Serial.println("2. FORWARD");
  Serial.println("3. REVERSE");
  Serial.println("4. READ CURRENT");
  Serial.println("+. INCREASE SPEED");
  Serial.println("-. DECREASE SPEED");
  Serial.println();

}

void loop() 
{
  char user_input;   
  while(Serial.available())
  {
    user_input = Serial.read(); 
    digitalWrite(EN_PIN_1, HIGH);
     
    if (user_input =='1')
    {
       Stop();
    }
    else if(user_input =='2')
    {
      Forward();
    }
    else if(user_input =='3')
    {
      Reverse();
    }
    else if(user_input =='+')
    {
      IncreaseSpeed();
    }
    else if(user_input =='-')
    {
      DecreaseSpeed();
    }
    else
    {
      Serial.println("Invalid option entered.");
    }
      
  }
}

void Stop()
{
  Serial.println("Stop");
  usMotor_Status = BRAKE;
  motorGo(MOTOR_1, usMotor_Status, 0);
}

void Forward()
{
  Serial.println("Forward");
  usMotor_Status = CW;
  motorGo(MOTOR_1, usMotor_Status, usSpeed);
}

void Reverse()
{
  Serial.println("Reverse");
  usMotor_Status = CCW;
  motorGo(MOTOR_1, usMotor_Status, usSpeed);
}

void IncreaseSpeed()
{
  usSpeed = usSpeed + 10;
  if(usSpeed > 255)
  {
    usSpeed = 255;  
  }
  
  Serial.print("Speed +: ");
  Serial.println(usSpeed);

  motorGo(MOTOR_1, usMotor_Status, usSpeed);
}

void DecreaseSpeed()
{
  usSpeed = usSpeed - 10;
  if(usSpeed < 0)
  {
    usSpeed = 0;  
  }
  
  Serial.print("Speed -: ");
  Serial.println(usSpeed);

  motorGo(MOTOR_1, usMotor_Status, usSpeed);
}

void motorGo(uint8_t motor, uint8_t direct, uint8_t pwm) 
{      
  if(motor == MOTOR_1)
  {
    if(direct == CW)
    {
      digitalWrite(MOTOR_A1_PIN, LOW); 
      digitalWrite(MOTOR_B1_PIN, HIGH);
    }
    else if(direct == CCW)
    {
      digitalWrite(MOTOR_A1_PIN, HIGH);
      digitalWrite(MOTOR_B1_PIN, LOW);      
    }
    else
    {
      digitalWrite(MOTOR_A1_PIN, LOW);
      digitalWrite(MOTOR_B1_PIN, LOW);            
    }
    
    analogWrite(PWM_MOTOR_1, pwm); 
    
  }
}